home *** CD-ROM | disk | FTP | other *** search
/ Skunkware 98 / Skunkware 98.iso / src / interp / perl5.005.tar.gz / perl5.005.tar / perl5.005 / lib / Cwd.pm < prev    next >
Text File  |  1998-07-06  |  10KB  |  386 lines
  1. package Cwd;
  2. require 5.000;
  3.  
  4. =head1 NAME
  5.  
  6. getcwd - get pathname of current working directory
  7.  
  8. =head1 SYNOPSIS
  9.  
  10.     use Cwd;
  11.     $dir = cwd;
  12.  
  13.     use Cwd;
  14.     $dir = getcwd;
  15.  
  16.     use Cwd;
  17.     $dir = fastgetcwd;
  18.  
  19.     use Cwd 'chdir';
  20.     chdir "/tmp";
  21.     print $ENV{'PWD'};
  22.  
  23.     use Cwd 'abs_path';
  24.     print abs_path($ENV{'PWD'});
  25.  
  26.     use Cwd 'fast_abs_path';
  27.     print fast_abs_path($ENV{'PWD'});
  28.  
  29. =head1 DESCRIPTION
  30.  
  31. The getcwd() function re-implements the getcwd(3) (or getwd(3)) functions
  32. in Perl.
  33.  
  34. The abs_path() function takes a single argument and returns the
  35. absolute pathname for that argument. It uses the same algoritm as
  36. getcwd(). (actually getcwd() is abs_path("."))
  37.  
  38. The fastcwd() function looks the same as getcwd(), but runs faster.
  39. It's also more dangerous because it might conceivably chdir() you out
  40. of a directory that it can't chdir() you back into.  If fastcwd
  41. encounters a problem it will return undef but will probably leave you
  42. in a different directory.  For a measure of extra security, if
  43. everything appears to have worked, the fastcwd() function will check
  44. that it leaves you in the same directory that it started in. If it has
  45. changed it will C<die> with the message "Unstable directory path,
  46. current directory changed unexpectedly". That should never happen.
  47.  
  48. The fast_abs_path() function looks the same as abs_path(), but runs faster.
  49. And like fastcwd() is more dangerous.
  50.  
  51. The cwd() function looks the same as getcwd and fastgetcwd but is
  52. implemented using the most natural and safe form for the current
  53. architecture. For most systems it is identical to `pwd` (but without
  54. the trailing line terminator).
  55.  
  56. It is recommended that cwd (or another *cwd() function) is used in
  57. I<all> code to ensure portability.
  58.  
  59. If you ask to override your chdir() built-in function, then your PWD
  60. environment variable will be kept up to date.  (See
  61. L<perlsub/Overriding Builtin Functions>.) Note that it will only be
  62. kept up to date if all packages which use chdir import it from Cwd.
  63.  
  64. =cut
  65.  
  66. ## use strict;
  67.  
  68. use Carp;
  69.  
  70. $VERSION = '2.01';
  71.  
  72. require Exporter;
  73. @ISA = qw(Exporter);
  74. @EXPORT = qw(cwd getcwd fastcwd fastgetcwd);
  75. @EXPORT_OK = qw(chdir abs_path fast_abs_path);
  76.  
  77.  
  78. # The 'natural and safe form' for UNIX (pwd may be setuid root)
  79.  
  80. sub _backtick_pwd {
  81.     my $cwd;
  82.     chop($cwd = `pwd`);
  83.     $cwd;
  84. }
  85.  
  86. # Since some ports may predefine cwd internally (e.g., NT)
  87. # we take care not to override an existing definition for cwd().
  88.  
  89. *cwd = \&_backtick_pwd unless defined &cwd;
  90.  
  91.  
  92. # By Brandon S. Allbery
  93. #
  94. # Usage: $cwd = getcwd();
  95.  
  96. sub getcwd
  97. {
  98.     abs_path('.');
  99. }
  100.  
  101. # By John Bazik
  102. #
  103. # Usage: $cwd = &fastcwd;
  104. #
  105. # This is a faster version of getcwd.  It's also more dangerous because
  106. # you might chdir out of a directory that you can't chdir back into.
  107.     
  108. # List of metachars taken from do_exec() in doio.c
  109. my $quoted_shell_meta = quotemeta('$&*(){}[]";\\|?<>~`'."'\n");
  110.  
  111. sub fastcwd {
  112.     my($odev, $oino, $cdev, $cino, $tdev, $tino);
  113.     my(@path, $path);
  114.     local(*DIR);
  115.  
  116.     my($orig_cdev, $orig_cino) = stat('.');
  117.     ($cdev, $cino) = ($orig_cdev, $orig_cino);
  118.     for (;;) {
  119.     my $direntry;
  120.     ($odev, $oino) = ($cdev, $cino);
  121.     CORE::chdir('..') || return undef;
  122.     ($cdev, $cino) = stat('.');
  123.     last if $odev == $cdev && $oino == $cino;
  124.     opendir(DIR, '.') || return undef;
  125.     for (;;) {
  126.         $direntry = readdir(DIR);
  127.         last unless defined $direntry;
  128.         next if $direntry eq '.';
  129.         next if $direntry eq '..';
  130.  
  131.         ($tdev, $tino) = lstat($direntry);
  132.         last unless $tdev != $odev || $tino != $oino;
  133.     }
  134.     closedir(DIR);
  135.     return undef unless defined $direntry; # should never happen
  136.     unshift(@path, $direntry);
  137.     }
  138.     $path = '/' . join('/', @path);
  139.     # At this point $path may be tainted (if tainting) and chdir would fail.
  140.     # To be more useful we untaint it then check that we landed where we started.
  141.     $path = $1 if $path =~ /^(.*)$/;    # untaint
  142.     CORE::chdir($path) || return undef;
  143.     ($cdev, $cino) = stat('.');
  144.     die "Unstable directory path, current directory changed unexpectedly"
  145.     if $cdev != $orig_cdev || $cino != $orig_cino;
  146.     $path;
  147. }
  148.  
  149.  
  150. # Keeps track of current working directory in PWD environment var
  151. # Usage:
  152. #    use Cwd 'chdir';
  153. #    chdir $newdir;
  154.  
  155. my $chdir_init = 0;
  156.  
  157. sub chdir_init {
  158.     if ($ENV{'PWD'} and $^O ne 'os2' and $^O ne 'dos') {
  159.     my($dd,$di) = stat('.');
  160.     my($pd,$pi) = stat($ENV{'PWD'});
  161.     if (!defined $dd or !defined $pd or $di != $pi or $dd != $pd) {
  162.         $ENV{'PWD'} = cwd();
  163.     }
  164.     }
  165.     else {
  166.     $ENV{'PWD'} = cwd();
  167.     }
  168.     # Strip an automounter prefix (where /tmp_mnt/foo/bar == /foo/bar)
  169.     if ($ENV{'PWD'} =~ m|(/[^/]+(/[^/]+/[^/]+))(.*)|) {
  170.     my($pd,$pi) = stat($2);
  171.     my($dd,$di) = stat($1);
  172.     if (defined $pd and defined $dd and $di == $pi and $dd == $pd) {
  173.         $ENV{'PWD'}="$2$3";
  174.     }
  175.     }
  176.     $chdir_init = 1;
  177. }
  178.  
  179. sub chdir {
  180.     my $newdir = shift || '';    # allow for no arg (chdir to HOME dir)
  181.     $newdir =~ s|///*|/|g;
  182.     chdir_init() unless $chdir_init;
  183.     return 0 unless CORE::chdir $newdir;
  184.     if ($^O eq 'VMS') { return $ENV{'PWD'} = $ENV{'DEFAULT'} }
  185.  
  186.     if ($newdir =~ m#^/#) {
  187.     $ENV{'PWD'} = $newdir;
  188.     } else {
  189.     my @curdir = split(m#/#,$ENV{'PWD'});
  190.     @curdir = ('') unless @curdir;
  191.     my $component;
  192.     foreach $component (split(m#/#, $newdir)) {
  193.         next if $component eq '.';
  194.         pop(@curdir),next if $component eq '..';
  195.         push(@curdir,$component);
  196.     }
  197.     $ENV{'PWD'} = join('/',@curdir) || '/';
  198.     }
  199.     1;
  200. }
  201.  
  202. # Taken from Cwd.pm It is really getcwd with an optional
  203. # parameter instead of '.'
  204. #
  205.  
  206. sub abs_path
  207. {
  208.     my $start = @_ ? shift : '.';
  209.     my($dotdots, $cwd, @pst, @cst, $dir, @tst);
  210.  
  211.     unless (@cst = stat( $start ))
  212.     {
  213.     carp "stat($start): $!";
  214.     return '';
  215.     }
  216.     $cwd = '';
  217.     $dotdots = $start;
  218.     do
  219.     {
  220.     $dotdots .= '/..';
  221.     @pst = @cst;
  222.     unless (opendir(PARENT, $dotdots))
  223.     {
  224.         carp "opendir($dotdots): $!";
  225.         return '';
  226.     }
  227.     unless (@cst = stat($dotdots))
  228.     {
  229.         carp "stat($dotdots): $!";
  230.         closedir(PARENT);
  231.         return '';
  232.     }
  233.     if ($pst[0] == $cst[0] && $pst[1] == $cst[1])
  234.     {
  235.         $dir = undef;
  236.     }
  237.     else
  238.     {
  239.         do
  240.         {
  241.         unless (defined ($dir = readdir(PARENT)))
  242.             {
  243.             carp "readdir($dotdots): $!";
  244.             closedir(PARENT);
  245.             return '';
  246.         }
  247.         $tst[0] = $pst[0]+1 unless (@tst = lstat("$dotdots/$dir"))
  248.         }
  249.         while ($dir eq '.' || $dir eq '..' || $tst[0] != $pst[0] ||
  250.            $tst[1] != $pst[1]);
  251.     }
  252.     $cwd = (defined $dir ? "$dir" : "" ) . "/$cwd" ;
  253.     closedir(PARENT);
  254.     } while (defined $dir);
  255.     chop($cwd) unless $cwd eq '/'; # drop the trailing /
  256.     $cwd;
  257. }
  258.  
  259. sub fast_abs_path {
  260.     my $cwd = getcwd();
  261.     my $path = shift || '.';
  262.     CORE::chdir($path) || croak "Cannot chdir to $path:$!";
  263.     my $realpath = getcwd();
  264.     CORE::chdir($cwd)  || croak "Cannot chdir back to $cwd:$!";
  265.     $realpath;
  266. }
  267.  
  268.  
  269. # --- PORTING SECTION ---
  270.  
  271. # VMS: $ENV{'DEFAULT'} points to default directory at all times
  272. # 06-Mar-1996  Charles Bailey  bailey@genetics.upenn.edu
  273. # Note: Use of Cwd::chdir() causes the logical name PWD to be defined
  274. #   in the process logical name table as the default device and directory
  275. #   seen by Perl. This may not be the same as the default device
  276. #   and directory seen by DCL after Perl exits, since the effects
  277. #   the CRTL chdir() function persist only until Perl exits.
  278.  
  279. sub _vms_cwd {
  280.     return $ENV{'DEFAULT'};
  281. }
  282.  
  283. sub _vms_abs_path {
  284.     return $ENV{'DEFAULT'} unless @_;
  285.     my $path = VMS::Filespec::pathify($_[0]);
  286.     croak("Invalid path name $_[0]") unless defined $path;
  287.     return VMS::Filespec::rmsexpand($path);
  288. }
  289.  
  290. sub _os2_cwd {
  291.     $ENV{'PWD'} = `cmd /c cd`;
  292.     chop $ENV{'PWD'};
  293.     $ENV{'PWD'} =~ s:\\:/:g ;
  294.     return $ENV{'PWD'};
  295. }
  296.  
  297. sub _win32_cwd {
  298.     $ENV{'PWD'} = Win32::GetCwd();
  299.     $ENV{'PWD'} =~ s:\\:/:g ;
  300.     return $ENV{'PWD'};
  301. }
  302.  
  303. *_NT_cwd = \&_win32_cwd if (!defined &_NT_cwd && 
  304.                             defined &Win32::GetCwd);
  305.  
  306. *_NT_cwd = \&_os2_cwd unless defined &_NT_cwd;
  307.  
  308. sub _dos_cwd {
  309.     if (!defined &Dos::GetCwd) {
  310.         $ENV{'PWD'} = `command /c cd`;
  311.         chop $ENV{'PWD'};
  312.         $ENV{'PWD'} =~ s:\\:/:g ;
  313.     } else {
  314.         $ENV{'PWD'} = Dos::GetCwd();
  315.     }
  316.     return $ENV{'PWD'};
  317. }
  318.  
  319. sub _qnx_cwd {
  320.     $ENV{'PWD'} = `/usr/bin/fullpath -t`;
  321.     chop $ENV{'PWD'};
  322.     return $ENV{'PWD'};
  323. }
  324.  
  325. sub _qnx_abs_path {
  326.     my $path = shift || '.';
  327.     my $realpath=`/usr/bin/fullpath -t $path`;
  328.     chop $realpath;
  329.     return $realpath;
  330. }
  331.  
  332. {
  333.     local $^W = 0;    # assignments trigger 'subroutine redefined' warning
  334.  
  335.     if ($^O eq 'VMS') {
  336.         *cwd        = \&_vms_cwd;
  337.         *getcwd        = \&_vms_cwd;
  338.         *fastcwd    = \&_vms_cwd;
  339.         *fastgetcwd    = \&_vms_cwd;
  340.         *abs_path    = \&_vms_abs_path;
  341.         *fast_abs_path    = \&_vms_abs_path;
  342.     }
  343.     elsif ($^O eq 'NT' or $^O eq 'MSWin32') {
  344.         # We assume that &_NT_cwd is defined as an XSUB or in the core.
  345.         *cwd        = \&_NT_cwd;
  346.         *getcwd        = \&_NT_cwd;
  347.         *fastcwd    = \&_NT_cwd;
  348.         *fastgetcwd    = \&_NT_cwd;
  349.         *abs_path    = \&fast_abs_path;
  350.     }
  351.     elsif ($^O eq 'os2') {
  352.         # sys_cwd may keep the builtin command
  353.         *cwd        = defined &sys_cwd ? \&sys_cwd : \&_os2_cwd;
  354.         *getcwd        = \&cwd;
  355.         *fastgetcwd    = \&cwd;
  356.         *fastcwd    = \&cwd;
  357.         *abs_path    = \&fast_abs_path;
  358.     }
  359.     elsif ($^O eq 'dos') {
  360.         *cwd        = \&_dos_cwd;
  361.         *getcwd        = \&_dos_cwd;
  362.         *fastgetcwd    = \&_dos_cwd;
  363.         *fastcwd    = \&_dos_cwd;
  364.         *abs_path    = \&fast_abs_path;
  365.     }
  366.     elsif ($^O eq 'qnx') {
  367.         *cwd        = \&_qnx_cwd;
  368.         *getcwd        = \&_qnx_cwd;
  369.         *fastgetcwd    = \&_qnx_cwd;
  370.         *fastcwd    = \&_qnx_cwd;
  371.         *abs_path    = \&_qnx_abs_path;
  372.         *fast_abs_path    = \&_qnx_abs_path;
  373.     }
  374. }
  375.  
  376. # package main; eval join('',<DATA>) || die $@;    # quick test
  377.  
  378. 1;
  379.  
  380. __END__
  381. BEGIN { import Cwd qw(:DEFAULT chdir); }
  382. print join("\n", cwd, getcwd, fastcwd, "");
  383. chdir('..');
  384. print join("\n", cwd, getcwd, fastcwd, "");
  385. print "$ENV{PWD}\n";
  386.